Поиск номера строки и столбца в двухмерной таблице - MS Excel

[Артем Кирсанов]

Добрый день.
На форуме есть топики с таким названием, я их просмотрел, но ни в одном не нашел решения моей задачи.
Я знаком с работой функций ВПР, Поискпоз, Индекс. Применял их для вывода значения в ячейке когда известны номер строки и столбца. А задачу от обратного решить не могу.
Суть вот в чем.
Есть произвольная таблица в которой много ячеек.
В одной из ячеек таблицы есть искомый текст (слово). Нужно получить значения столбца и строки ячейки, в которой находится этот текст.

В частности для слова "Сон". нужно вывести номер строки и столбца ячейки, в которой оно находится

Помогите плиз, очень надо

[vikttur]

Код Выделить Развернуть

=МИН(ЕСЛИ(B4:D7="Сон";СТОЛБЕЦ(B4:D7)))
формула массива, ввод тремя клавишами.
Для строки аналогично.

[zs5]

Исходя из вопроса форума, формулу, предложенную vikttur, необходимо привести в следующий вид:

Код Выделить Развернуть

=АДРЕС(МИН(ЕСЛИ(A1:E247=H4;СТРОКА(A1:E247)));МИН(ЕСЛИ(A1:E247=H4;СТОЛБЕЦ(A1:E247)))),
где Н4 - искомый текст

[vikttur]

Исходя из вопроса...

...нужны два значения:

...вывести номер строки и столбца ячейки

[zs5]

Тогда:

Код Выделить Развернуть

=СЦЕПИТЬ("Столбец";" ";МИН(ЕСЛИ(A1:E247="Сон";СТОЛБЕЦ(A1:E247)));";";"Строка"; " ";МИН(ЕСЛИ(A1:E247="Сон";СТРОКА(A1:E247))))

[zs5]

Тогда:

Код Выделить Развернуть

=СЦЕПИТЬ("Столбец";" ";МИН(ЕСЛИ(A1:E247="Сон";СТОЛБЕЦ(A1:E247)));";";"Строка"; " ";МИН(ЕСЛИ(A1:E247="Сон";СТРОКА(A1:E247))))

или

Код Выделить Развернуть

="Столбец"&" №"& МИН(ЕСЛИ(A1:E247=H4;СТОЛБЕЦ(A1:E247)))&";"&"Строка"&" №"& МИН(ЕСЛИ(A1:E247=H4;СТРОКА(A1:E247)))
вариант, в каждом столбце формула:

Код Выделить Развернуть

=ЕСЛИОШИБКА(ПОИСКПОЗ($H$4;B4:B7;0); "")

[Артем Кирсанов]

ребята, спасибо за помощь.
помогло.