Подбор ближайшых значений двух параметров

[dovis]

Добрый день,

может ли мне кто нибудь помочь с следующей задачей. Я имею таблицу с комбинациями двух параметров, то есть два столбца с параметрами электродвигателей - номинальная мощность и  обороты в минуту. К стати значений обоих столбцов по определенному порядку повторяется. А так же имею два ячейки с расчетными теми же самыми параметрами. Суть задачи подобрать из таблицы строку с ближайшыми к расчетным значениям в большую сторону и вывести в отдельные ячейки. Какую функцию или комбинацию функций надо изпользовать в етом случае? (файл приложил).

Спасибо заранее

[_Boroda_]

можно так
Для В6

Код Выделить Развернуть

=ИНДЕКС(F$3:F$159;ПОИСКПОЗ(МИН(ЕСЛИ(F$3:F$159<B2;1000000;F$3:F$159)*ЕСЛИ(G$3:G$159<B3;1000000;G$3:G$159));ЕСЛИ(F$3:F$159<B2;1000000;F$3:F$159)*ЕСЛИ(G$3:G$159<B3;1000000;G$3:G$159);0))
Для В7

Код Выделить Развернуть

=ИНДЕКС(G$3:G$159;ПОИСКПОЗ(МИН(ЕСЛИ(F$3:F$159<B2;1000000;F$3:F$159)*ЕСЛИ(G$3:G$159<B3;1000000;G$3:G$159));ЕСЛИ(F$3:F$159<B2;1000000;F$3:F$159)*ЕСЛИ(G$3:G$159<B3;1000000;G$3:G$159);0))
Формулы массива. Вводить нажатием Контрл Шифт Ентер вместо обычного Ентера

Выводит пару, у которой каждое значение больше исходного и их произведение минимально

[MCH]

или так:

Код Выделить Развернуть

=ИНДЕКС(F3:F159;ПОИСКПОЗ(МИН(((B2-(F3:F159>=B2)*F3:F159)/B2*(B3-(G3:G159>=B3)*G3:G159)/B2)^2);((B2-(F3:F159>=B2)*F3:F159)/B2*(B3-(G3:G159>=B3)*G3:G159)/B2)^2;))

Код Выделить Развернуть

=ИНДЕКС(G3:G159;ПОИСКПОЗ(МИН(((B2-(F3:F159>=B2)*F3:F159)/B2*(B3-(G3:G159>=B3)*G3:G159)/B2)^2);((B2-(F3:F159>=B2)*F3:F159)/B2*(B3-(G3:G159>=B3)*G3:G159)/B2)^2;))

[_Boroda_]

MCH

Проверь 1,71 и 2849

[IKor]

Чтобы избежать использование формул массива, можно использовать дополнительный столбец (хотя я и не слишком люблю их использовать). Формула та же, но разобраться с ней проще.

Кроме того, можно результаты поиска выводить не в явном виде - наилучший результат в строке такой-то, а предлагать на выбор несколько вариантов, ближайших к наилучшему. Это реализовано при помощи условного форматирования, функции НАИМЕНЬШИЙ() и того же дополнителного столбца.

[dovis]

Спасибо большое всем за помощь и советы. Теперь осталось изучить синтаксис функций, которые вы предложили

[MCH]

MCH

Проверь 1,71 и 2849

Да, накосячил немного.
можно еще так:

Код Выделить Развернуть

=ИНДЕКС(F$3:F$159;ПОИСКПОЗ(МИН(ЕСЛИ((B$2<=F$3:F$159)*(B$3<=G$3:G$159);F$3:F$159/B$2+G$3:G$159/B$3));ЕСЛИ((B$2<=F$3:F$159)*(B$3<=G$3:G$159);F$3:F$159/B$2+G$3:G$159/B$3);))

Код Выделить Развернуть

=ИНДЕКС(G$3:G$159;ПОИСКПОЗ(МИН(ЕСЛИ((B$2<=F$3:F$159)*(B$3<=G$3:G$159);F$3:F$159/B$2+G$3:G$159/B$3));ЕСЛИ((B$2<=F$3:F$159)*(B$3<=G$3:G$159);F$3:F$159/B$2+G$3:G$159/B$3);))

или даже так:

Код Выделить Развернуть

=ИНДЕКС(F$3:F$159;ПОИСКПОЗ(МИН(ЕСЛИ((B$2<=F$3:F$159)*(B$3<=G$3:G$159);F$3:F$159/B$2+G$3:G$159/B$3));F$3:F$159/B$2+G$3:G$159/B$3;))

Код Выделить Развернуть

=ИНДЕКС(G$3:G$159;ПОИСКПОЗ(МИН(ЕСЛИ((B$2<=F$3:F$159)*(B$3<=G$3:G$159);F$3:F$159/B$2+G$3:G$159/B$3));F$3:F$159/B$2+G$3:G$159/B$3;))