Как перебрать диапазон с конца

[Poltava]

Вот фрагмент кода который ищет в диапазоне ячейку со значением "итого" и определяет ее позицию

Код Выделить Развернуть

    Dim tCell As Variant
   For Each tCell In Range("C:C").SpecialCells(xlConstants, 23)
       If tCell.Value = "Итого" Then
           Exit For
       End If
       Flag = Flag + 1
   Next tCell
   Index = tCell.Row
Код вроде работает без претензий и свою функцию выполняет. Но он допустим перебирает ячейки от С1 до С500000 а значение итого как правило именно в ячейке С500000 следовательно код должен выполниться 500000 тысяч раз!!! а оно нам надо
Отсюдова возникает задачя как перебрать этот же диапазон но в обратном порядне начиная с С500000 так код должен будет выполниться всего раз 10  как по мне прирост скорости должен быть налицо.

[RAN]

Не подойдет?

Код Выделить Развернуть

Sub qq()
Dim i&
For i = Cells(Rows.Count, "C").End(xlUp).Row To 1 Step -1
If Cells(i, "C").Value = "Итого" Then Index = i: Exit For
Next
End Sub

[Poltava]

Да спасибо я тоже думал о таком варианте. Но все же хотел узнать именно возможно ли перебрать диапазон с конца именно в таком синтаксисе.

Код Выделить Развернуть

For Each tCell In Range("C:C").SpecialCells(xlConstants, 23)
Думал может есть какой то параметр типа Step -1 но очевидно это невозможно и нужно делать именно так как Вы предложили

[_Boroda_]

Если нужно найти значение в столбце, и оно там единственное (что следует из попытки искать сверху вниз и снизу вверх), то, по-моему, будет намного быстрее использовать функцию листа

Код Выделить Развернуть

Sub tt()
On Error Resume Next
n_ = WorksheetFunction.Match("Итого", Range("C:C"), 0)
On Error GoTo 0
End Sub
или обычным поиском

Код Выделить Развернуть

  r_ = Columns("C:C").Find(What:="Итого", After:=ActiveCell, LookIn:=xlValues, _
        LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False).Row

[Poltava]

Спасибо за подсказку будем пробовать

[Poltava]

Да перепробовал несколько способов вот результаты при условии что значение итого находилось в последней или предпоследней строке всего перебирались 4 файла. Но как по мне результаты какие то странные и либо я неверно организовал таймер либо одно из двух

Time  0  Index  1824 Time  0,03125  Index2  1824 Time  0  Index3  1824 Time  0  Index4  1824

Time  0,03125  Index  3308 Time  0,03125  Index2  3308 Time  0  Index3  3308 Time  0  Index4  3308

Time  0,015625  Index  2929 Time  0,03125  Index2  2929 Time  0  Index3  2929 Time  0  Index4  2929

Time  0,015625  Index  2465 Time  0,03125  Index2  2465 Time  0  Index3  2465 Time  0  Index4  2465

Ну и сам код

Код Выделить Развернуть

    t = Timer
    Dim tCell As Variant
    For Each tCell In Range("C:C").SpecialCells(xlConstants, 23)
        If tCell.Value = "Итого" Then
            Exit For
        End If
    Next tCell
    Index = tCell.Row
    Debug.Print "Time "; Timer - t; " Index "; Index
   
    t = Timer
    Index2 = Range("C:C").SpecialCells(xlConstants, 23).Find(What:="Итого", After:=Cells(1, 3), LookIn:=xlValues, _
            LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
            MatchCase:=False, SearchFormat:=False).Row
    Debug.Print "Time "; Timer - t; " Index2 "; Index2
   
    t = Timer
    Dim i&
    For i = Cells(Rows.Count, "C").End(xlUp).Row To 1 Step -1
        If Cells(i, "C").Value = "Итого" Then Index3 = i: Exit For
    Next
    Debug.Print "Time "; Timer - t; " Index3 "; Index3
   
    t = Timer
    On Error Resume Next
        Index4 = WorksheetFunction.Match("Итого", Range("C:C"), 0)
    On Error GoTo 0
    Debug.Print "Time "; Timer - t; " Index4 "; Index4