ПОИСКПОЗ() с повторяющимися данными

[0mega]

Здравствуйте.
2003
sub no

Столбец "А" имеет повторяющиеся записи
14
9
64
9
14

Необходимо найти все "9"
=ПОИСКПОЗ(9;$A$1:$A$20;0) =2
Находит первую девятку.
Как найти вторую (4) и n-ую

[Михаил С.]

как-то так

[_Boroda_]

Еще 5 вариантов
формулы массива

Код Выделить Развернуть

=ЕСЛИ(СЧЁТЕСЛИ(A$1:A$20;D$1)<СТРОКА()-4;"";НАИМЕНЬШИЙ(ЕСЛИ(A$1:A$20=D$1;СТРОКА(A$1:A$20));СТРОКА()-4))

Код Выделить Развернуть

=НАИМЕНЬШИЙ(ЕСЛИ(A$1:A$20=D$1;СТРОКА(A$1:A$20));СТРОКА()-4)

Код Выделить Развернуть

=НАИМЕНЬШИЙ(ЕСЛИ(A$1:A$20=D$1;СТРОКА(A$1:A$20);999999);СТРОКА()-4)
обычные формулы

Код Выделить Развернуть

=ПОИСКПОЗ(D$1;ДВССЫЛ("A"&СУММ(E4;1)&":A20");)+E4

Код Выделить Развернуть

=ПОИСКПОЗ(D$1;СМЕЩ(A$1;СУММ(E4;1)-1;;СЧЁТ(A:A));)+E4
2, 4 и 5 лишнее убрано условным форматированием, 3 - форматом ячейки

[0mega]

Михаил, Александр,
Благодарю.
Даже представить не мог что здесь столько (!) решений.
Само-собой  _Boroda_ получил по репе
(похоже что на этом сайте с этим жаргоном не знакомы, но он знает о чем разговор)

P.S.
Своей фантазии хватило на 4-ую формулу. Но, по незнанию, использовал 2 амперсанда
=ПОИСКПОЗ(D$1;ДВССЫЛ("A"&СУММ(E4;1)&":"&A20); )+E4
Естественно, машина высказалась недружелюбно